DHT11 Sıcaklık ve Nem Sensörü Kullanımı

DHT11'in özellikleri

DHT11 oda koşullarını izlemek için yeterlidir; hassas ölçüm, eksi sıcaklıklar veya dış ortam için DHT21/22 ya da I²C'li AHT10/SHT serisi tercih edilmelidir. Yalnızca sıcaklık gerekiyorsa su geçirmez kılıflı DS18B20 daha doğrudur.

Bağlantı

Çıplak DHT11'in 4 bacağı vardır: VCC, DATA, boş, GND. Modül versiyonlarında 3 pin bulunur ve DATA hattındaki 10 kΩ pull-up direnci kartın üzerinde hazırdır. Çıplak sensör kullanıyorsanız DATA ile VCC arasına 4,7 – 10 kΩ direnç ekleyin. Kablo 1 – 2 metreyi geçiyorsa pull-up değerini düşürmek (4,7 kΩ) ve sensörün yanına 100 nF kondansatör koymak iletişimi güvenilir kılar.

// Kütüphane: "DHT sensor library" (Adafruit) — Kütüphane Yöneticisi'nden kurun
#include <DHT.h>

#define DHTPIN 2        // DATA pini
#define DHTTYPE DHT11   // DHT21 için: DHT21
DHT dht(DHTPIN, DHTTYPE);

void setup() {
  Serial.begin(9600);
  dht.begin();
}

void loop() {
  delay(2000);                        // DHT11 en fazla saniyede bir okunur
  float nem = dht.readHumidity();
  float sic = dht.readTemperature();  // °C
  if (isnan(nem) || isnan(sic)) {
    Serial.println("Okuma hatası: bağlantıyı kontrol edin");
    return;
  }
  Serial.print("Sıcaklık: "); Serial.print(sic); Serial.print(" °C  Nem: %");
  Serial.println(nem);
}

ESP32'de aynı kod çalışır; DATA için herhangi bir GPIO seçilebilir ve sensör 3,3 V ile beslenebilir.

Doğru ölçüm için ipuçları

• Sensörü regülatör, mikrodenetleyici veya LED gibi ısınan parçalardan uzak tutun; kart üzerindeki ısı sıcaklığı birkaç derece yüksek gösterir.
• Kutunun içinde kullanıyorsanız hava delikleri açın; nem sensörü havayla temas etmelidir.
• Doğrudan güneş ışığı ve yoğuşma (su damlası) ölçümü bozar ve sensöre zarar verir.
• Sensörü birkaç dakikada bir okumak çoğu uygulama için yeterlidir; sık okuma sensörü hafifçe ısıtır.

Bu yazıda kullanılan ürünler

Sensör karşılaştırması

Değerler üretici veri sayfalarındaki tipik değerlerdir; gerçek doğruluk kalibrasyon ve ortama bağlıdır.

Çiğlenme noktası hesabı

Nem ve sıcaklıktan çiğlenme noktasını (havanın yoğuşmaya başladığı sıcaklık) Magnus formülüyle hesaplayabilirsiniz: γ = ln(RH/100) + a·T/(b + T), T_d = b·γ / (a − γ); a = 17,62, b = 243,12 °C. 25 °C ve %60 nemde çiğlenme noktası 16,7 °C'dir; yüzey sıcaklığı bunun altına düşerse yoğuşma oluşur. Arduino'da şöyle kodlanır:

float ciglenme(float t, float rh) {
  const float a = 17.62, b = 243.12;
  float g = log(rh / 100.0) + (a * t) / (b + t);
  return (b * g) / (a - g);
}

Gürültüyü azaltmak: ortalama alma

DHT11'in tam sayı çözünürlüğü olduğundan değerler 1 °C adımlarla zıplar. Birkaç ölçümün ortalamasını almak zıplamayı yumuşatır:

float ortSicaklik(DHT &dht, int n) {
  float toplam = 0; int gecerli = 0;
  for (int i = 0; i < n; i++) {
    float s = dht.readTemperature();
    if (!isnan(s)) { toplam += s; gecerli++; }
    delay(1100);                 // DHT11 en az 1 saniye aralık ister
  }
  return gecerli ? toplam / gecerli : NAN;
}

Sorun giderme tablosu